Add a new rule haskell_prebuilt_library.

This rule forwards a prebuilt dependency, so that it may be
specified directly in `deps` rather than `prebuilt_dependencies`.

This gives progress on #75.  Similarly, it simplifies the use of Hazel,
which can now generate repositories for the prebuilt dependencies
just like for regular packages.

haskell/haskell.bzl

@@ -4,6 +4,7 @@ load(":private/providers.bzl",
   "HaskellBuildInfo",
   "HaskellLibraryInfo",
   "HaskellBinaryInfo",
+  "HaskellPrebuiltPackageInfo",
   "HaskellProtobufInfo",
   "CcSkylarkApiProviderHacked",
 )
@@ -226,6 +227,43 @@ $ bazel-bin/.../hello-lib-repl  # run the script
 ```
 """
 
+def _haskell_prebuilt_library(ctx):
+  # TODO: double-check it actually exists in ghc-pkg?
+  return [HaskellPrebuiltPackageInfo(
+            package = ctx.attr.package)]
+
+"""Wrap a prebuilt dependency as a rule.
+
+Example:
+  ```bzl
+  haskell_prebuilt_library(
+      name = "base_pkg",
+      package = "base",
+  )
+  haskell_library(
+      name = "hello-lib",
+      srcs = ["Lib.hs"],
+      deps = [
+          ":base",
+          "//hello-sublib:lib",
+      ],
+  )
+  ```
+
+This rule may wrap any prebuilt dependencies, i.e., GHC packages that aren't
+supplied by Bazel.  Depending on the wrapped rule eliminates the need to list
+the package name in prebuilt_dependencies.
+
+Often, rules of this type will be generated automatically by frameworks such
+as Hazel.
+"""
+haskell_prebuilt_library = rule(
+  _haskell_prebuilt_library,
+  attrs = dict(
+    package = attr.string(doc = "A non-Bazel-supplied GHC package name."),
+  ),
+)
+
 haskell_doc = _haskell_doc
 
 haskell_lint = _haskell_lint

haskell/private/dependencies.bzl

@@ -3,6 +3,7 @@ load(":private/providers.bzl",
   "HaskellBuildInfo",
   "HaskellBinaryInfo",
   "HaskellLibraryInfo",
+  "HaskellPrebuiltPackageInfo",
   "CcSkylarkApiProviderHacked",
 )
 load(":private/set.bzl", "set")
@@ -95,6 +96,19 @@ def gather_dep_info(ctx):
         external_libraries = dicts.add(acc.external_libraries, binfo.external_libraries),
         direct_prebuilt_deps = acc.direct_prebuilt_deps,
       )
+    elif HaskellPrebuiltPackageInfo in dep:
+      pkg = dep[HaskellPrebuiltPackageInfo].package
+      acc = HaskellBuildInfo(
+        package_ids = acc.package_ids,
+        package_confs = acc.package_confs,
+        package_caches = acc.package_caches,
+        static_libraries = acc.static_libraries,
+        dynamic_libraries = acc.dynamic_libraries,
+        interface_files = acc.interface_files,
+        prebuilt_dependencies = set.insert(acc.prebuilt_dependencies, pkg),
+        external_libraries = acc.external_libraries,
+        direct_prebuilt_deps = set.insert(acc.direct_prebuilt_deps, pkg),
+      )
     else:
       # If not a Haskell dependency, pass it through as-is to the
       # linking phase.

haskell/private/providers.bzl

@@ -60,6 +60,13 @@ HaskellBinaryInfo = provider(
   },
 )
 
+HaskellPrebuiltPackageInfo = provider(
+  doc = "Information about a prebuilt GHC package.",
+  fields = {
+    "package": "Package name",
+  },
+)
+
 HaddockInfo = provider(
   doc = "Haddock information.",
   fields = {

tests/prebuilt-library/BUILD

@@ -0,0 +1,36 @@
+package(default_testonly = 1)
+
+load(
+    "@io_tweag_rules_haskell//haskell:haskell.bzl",
+    "haskell_library",
+    "haskell_prebuilt_library",
+    "haskell_test",
+)
+
+haskell_prebuilt_library(
+  name = "bytestring",
+  package = "bytestring",
+)
+
+haskell_prebuilt_library(
+  name = "text",
+  package = "text",
+)
+
+haskell_library(
+    name = "Lib",
+    srcs = ["Lib.hs"],
+    prebuilt_dependencies = ["base"],
+    deps = [":bytestring"],
+)
+
+haskell_test(
+    name = "binary",
+    srcs = ["Bin.hs"],
+    main_file = "Bin.hs",
+    prebuilt_dependencies = ["base"],
+    deps = [
+        ":text",
+        ":Lib",
+    ],
+)

tests/prebuilt-library/Bin.hs

@@ -0,0 +1,8 @@
+module Main (main) where
+
+import qualified Data.Text.IO as T
+import qualified Data.Text.Encoding as E
+
+import Lib (message)
+
+main = T.putStrLn $ E.decodeUtf8 message

tests/prebuilt-library/Lib.hs

@@ -0,0 +1,5 @@
+module Lib (message) where
+
+import qualified Data.ByteString.Char8 as B
+
+message = B.pack "hello, world"