List process container images in preview mode

docs/config.md

@@ -1108,6 +1108,24 @@ The following settings are available:
 
 Read the {ref}`container-podman` page to learn more about how to use Podman containers with Nextflow.
 
+(config-preview)=
+
+### Scope `preview`
+
+:::{versionadded} 23.07.0-edge
+:::
+
+The `preview` scope controls the preview report that is generated when running a pipeline in preview mode (i.e. using the `-preview` command line option).
+
+`preview.directives`
+: The list of process directives to preview (default: `['container', 'cpus', 'memory', 'time']`).
+
+`preview.file`
+: Preview report file name. Must be a JSON file (default: `preview-<timestamp>.json`).
+
+`preview.overwrite`
+: When `true` overwrites any existing preview report with the same name.
+
 (config-process)=
 
 ### Scope `process`

modules/nextflow/src/main/groovy/nextflow/Session.groovy

@@ -65,6 +65,7 @@ import nextflow.script.ScriptRunner
 import nextflow.script.WorkflowMetadata
 import nextflow.spack.SpackConfig
 import nextflow.trace.AnsiLogObserver
+import nextflow.trace.PreviewReportWriter
 import nextflow.trace.TraceObserver
 import nextflow.trace.TraceObserverFactory
 import nextflow.trace.TraceRecord
@@ -468,6 +469,7 @@ class Session implements ISession {
         CH.broadcast()
 
         if( preview ) {
+            PreviewReportWriter.create(this).render()
             terminated = true
         }
         else {

modules/nextflow/src/main/groovy/nextflow/processor/TaskProcessor.groovy

@@ -367,6 +367,15 @@ class TaskProcessor {
 
     boolean hasErrors() { errorCount>0 }
 
+    /**
+     * Get a preview task config.
+     */
+    TaskConfig getPreviewConfig() {
+        def config = config.createTaskConfig()
+        config.context = new TaskContext(this)
+        return config
+    }
+
     protected void checkWarn(String msg, Map opts=null) {
         if( NF.isStrictMode() )
             throw new ProcessUnrecoverableException(msg)

modules/nextflow/src/main/groovy/nextflow/trace/PreviewReportWriter.groovy

@@ -0,0 +1,119 @@
+/*
+ * Copyright 2013-2023, Seqera Labs
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+package nextflow.trace
+
+import java.nio.file.Path
+
+import groovy.json.JsonBuilder
+import groovy.transform.CompileStatic
+import groovy.util.logging.Slf4j
+import nextflow.Session
+import nextflow.dag.DAG
+import nextflow.exception.AbortOperationException
+import nextflow.file.FileHelper
+import nextflow.util.Duration
+import nextflow.util.MemoryUnit
+/**
+ * Render the preview report when running a pipeline
+ * in preview mode.
+ *
+ * @author Ben Sherman <[email protected]>
+ */
+@Slf4j
+@CompileStatic
+class PreviewReportWriter implements TraceObserver {
+
+    static private final List<String> DEF_DIRECTIVES = ['container', 'cpus', 'memory', 'time']
+
+    static private final String DEF_FILE_NAME = "preview-${TraceHelper.launchTimestampFmt()}.json"
+
+    private DAG dag
+
+    private List<String> directives
+
+    private Path file
+
+    private boolean overwrite
+
+    static PreviewReportWriter create(Session session) {
+        final directives = session.config.navigate('preview.directives', DEF_DIRECTIVES) as List
+        def file = session.config.navigate('preview.file', DEF_FILE_NAME)
+        file = (file as Path).complete()
+        final overwrite = session.config.navigate('preview.overwrite', false) as boolean
+
+        return new PreviewReportWriter(session.dag, directives, file, overwrite)
+    }
+
+    PreviewReportWriter( DAG dag, List<String> directives, Path file, boolean overwrite ) {
+        this.dag = dag
+        this.directives = directives
+        this.file = file
+        this.overwrite = overwrite
+
+        // check file existance
+        final attrs = FileHelper.readAttributes(file)
+        if( attrs ) {
+            if( overwrite && (attrs.isDirectory() || !file.delete()) )
+                throw new AbortOperationException("Unable to overwrite existing preview file: ${file.toUriString()}")
+            else if( !overwrite )
+                throw new AbortOperationException("Preview file already exists: ${file.toUriString()} -- enable `preview.overwrite` in your config file to overwrite existing preview files")
+        }
+    }
+
+    void render() {
+        // get preview data
+        final jsonData = [:]
+
+        for( def vertex : dag.vertices ) {
+            // skip nodes that are not processes
+            final process = vertex.process
+            if( !process )
+                continue
+
+            // get preview task config
+            final taskConfig = process.getPreviewConfig()
+
+            // get preview for each directive
+            def config = [:]
+
+            for( def directive : directives ) {
+                // try to resolve directive value
+                def value = null
+                try {
+                    value = taskConfig.get(directive)
+                }
+                catch( Exception e ) {
+                    log.warn1 "Unable to preview directive `${directive}` for process `${process.name}`: ${e}"
+                }
+
+                // convert custom types to string values
+                if( value instanceof Duration || value instanceof MemoryUnit )
+                    value = value.toString()
+
+                // add directive value if it was resolved
+                if( value != null )
+                    config[directive] = value
+            }
+
+            jsonData[process.name] = config
+        }
+
+        // write preview data to file
+        file.text = new JsonBuilder(jsonData).toString()
+    }
+
+}