Updated deprecated autoconf macros

configure.ac

@@ -1,7 +1,7 @@
 #                                               -*- Autoconf -*-
 # Process this file with autoconf to produce a configure script.
 
-AC_PREREQ(2.68)
+AC_PREREQ([2.68])
 AC_INIT([ideviceinstaller], [m4_esyscmd(./git-version-gen $RELEASE_VERSION)], [https://github.com/libimobiledevice/ideviceinstaller/issues], [], [https://libimobiledevice.org])
 AM_INIT_AUTOMAKE([dist-bzip2 no-dist-gzip check-news])
 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
@@ -25,7 +25,6 @@ PKG_CHECK_MODULES(libplist, libplist-2.0 >= 2.3.0)
 PKG_CHECK_MODULES(libzip, libzip >= 0.10)
 
 # Checks for header files.
-AC_HEADER_STDC
 AC_CHECK_HEADERS([stdint.h stdlib.h string.h])
 
 # Checks for typedefs, structures, and compiler characteristics.
@@ -44,16 +43,16 @@ AC_CHECK_FUNCS([strdup strerror asprintf vasprintf])
 # Check for lstat
 
 AC_MSG_CHECKING([whether lstat is available])
-AC_TRY_LINK([
+AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 #include <sys/types.h>
 #include <sys/stat.h>
 #if defined(HAVE_UNISTD_H)
 #include <unistd.h>
 #endif
-],[
+]],[[
 struct stat st;
 lstat("/tmp", &st);
-], [have_lstat="yes"], [have_lstat="no"])
+]])], [have_lstat="yes"], [have_lstat="no"])
 AC_MSG_RESULT([${have_lstat}])
 
 if test "x${have_lstat}" = "xyes" ; then

m4/as-compiler-flag.m4

@@ -18,7 +18,7 @@ AC_DEFUN([AS_COMPILER_FLAG],
   save_CFLAGS="$CFLAGS"
   CFLAGS="$CFLAGS $1"
 
-  AC_TRY_COMPILE([ ], [], [flag_ok=yes], [flag_ok=no])
+  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [flag_ok=yes], [flag_ok=no])
   CFLAGS="$save_CFLAGS"
 
   if test "X$flag_ok" = Xyes ; then
@@ -44,7 +44,7 @@ AC_DEFUN([AS_COMPILER_FLAGS],
   do
     save_CFLAGS="$CFLAGS"
     CFLAGS="$CFLAGS $each"
-    AC_TRY_COMPILE([ ], [], [flag_ok=yes], [flag_ok=no])
+    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [flag_ok=yes], [flag_ok=no])
     CFLAGS="$save_CFLAGS"
 
     if test "X$flag_ok" = Xyes ; then