Add support for defaults

contracts/Loan.sol

@@ -14,6 +14,7 @@ import "./FundingVault.sol";
  */
 contract Loan is ILoan {
     IServiceConfiguration private immutable _serviceConfiguration;
+    address private immutable _factory;
     ILoanLifeCycleState private _state = ILoanLifeCycleState.Requested;
     address private immutable _borrower;
     address private immutable _pool;
@@ -78,6 +79,7 @@ contract Loan is ILoan {
 
     constructor(
         IServiceConfiguration serviceConfiguration,
+        address factory,
         address borrower,
         address pool,
         uint256 duration_,
@@ -89,6 +91,7 @@ contract Loan is ILoan {
         uint256 dropDeadTimestamp
     ) {
         _serviceConfiguration = serviceConfiguration;
+        _factory = factory;
         _borrower = borrower;
         _pool = pool;
         _collateralVault = new CollateralVault(address(this));
@@ -231,6 +234,21 @@ contract Loan is ILoan {
         return amount;
     }
 
+    /**
+     * @inheritdoc ILoan
+     */
+    function markDefaulted()
+        external
+        override
+        onlyPool
+        atState(ILoanLifeCycleState.Funded)
+        returns (ILoanLifeCycleState)
+    {
+        _state = ILoanLifeCycleState.Defaulted;
+        emit LifeCycleStateTransition(_state);
+        return _state;
+    }
+
     function state() external view returns (ILoanLifeCycleState) {
         return _state;
     }
@@ -243,6 +261,10 @@ contract Loan is ILoan {
         return _pool;
     }
 
+    function factory() external view returns (address) {
+        return _factory;
+    }
+
     function dropDeadTimestamp() external view returns (uint256) {
         return _dropDeadTimestamp;
     }

contracts/LoanFactory.sol

@@ -13,6 +13,11 @@ contract LoanFactory {
      */
     IServiceConfiguration private _serviceConfiguration;
 
+    /**
+     * @dev Mapping of created loans
+     */
+    mapping(address => bool) private _isLoan;
+
     /**
      * @dev Emitted when a Loan is created.
      */
@@ -43,6 +48,7 @@ contract LoanFactory {
         );
         Loan loan = new Loan(
             _serviceConfiguration,
+            address(this),
             borrower,
             pool,
             duration,
@@ -55,6 +61,14 @@ contract LoanFactory {
         );
         address addr = address(loan);
         emit LoanCreated(addr);
+        _isLoan[addr] = true;
         return addr;
     }
+
+    /**
+     * @dev Checks whether the address corresponds to a created loan for this factory
+     */
+    function isLoan(address loan) public view returns (bool) {
+        return _isLoan[loan];
+    }
 }

contracts/Pool.sol

@@ -3,6 +3,7 @@ pragma solidity ^0.8.16;
 
 import "./interfaces/ILoan.sol";
 import "./interfaces/IPool.sol";
+import "./interfaces/IServiceConfiguration.sol";
 import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
 import {IERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
 import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
@@ -19,6 +20,7 @@ contract Pool is IPool, ERC20 {
 
     IPoolLifeCycleState private _poolLifeCycleState;
     address private _manager;
+    IServiceConfiguration private _serviceConfiguration;
     IERC20 private _liquidityAsset;
     IPoolConfigurableSettings private _poolSettings;
     FirstLossVault private _firstLossVault;
@@ -94,19 +96,22 @@ contract Pool is IPool, ERC20 {
      * @param liquidityAsset asset held by the poo
      * @param poolManager manager of the pool
      * @param poolSettings configurable settings for the pool
+     * @param serviceConfiguration address of global service configuration
      * @param tokenName Name used for issued pool tokens
      * @param tokenSymbol Symbol used for issued pool tokens
      */
     constructor(
         address liquidityAsset,
         address poolManager,
+        address serviceConfiguration,
         IPoolConfigurableSettings memory poolSettings,
         string memory tokenName,
         string memory tokenSymbol
     ) ERC20(tokenName, tokenSymbol) {
         _liquidityAsset = IERC20(liquidityAsset);
         _poolSettings = poolSettings;
         _manager = poolManager;
+        _serviceConfiguration = IServiceConfiguration(serviceConfiguration);
         _firstLossVault = new FirstLossVault(address(this), liquidityAsset);
         _setPoolLifeCycleState(IPoolLifeCycleState.Initialized);
     }
@@ -221,13 +226,31 @@ contract Pool is IPool, ERC20 {
 
         _liquidityAsset.safeApprove(address(loan), loan.principal());
         loan.fund();
+        _accountings.activeLoanPrincipals += loan.principal();
     }
 
     /**
-     * @dev Called by the pool manager, marks a loan as in default, updating pool accounting and allowing loan
-     * collateral to be claimed.
+     * @inheritdoc IPool
      */
-    function markLoanAsInDefault(address) external onlyManager {}
+    function defaultLoan(address loan)
+        external
+        onlyManager
+        atState(IPoolLifeCycleState.Active)
+    {
+        require(loan != address(0), "Pool: 0 address");
+        require(
+            PoolLib.isPoolLoan(
+                loan,
+                address(_serviceConfiguration),
+                address(this)
+            ),
+            "Pool: invalid loan"
+        );
+
+        ILoan(loan).markDefaulted();
+        _accountings.activeLoanPrincipals -= ILoan(loan).principal();
+        emit LoanDefaulted(loan);
+    }
 
     /*//////////////////////////////////////////////////////////////
                     Withdrawal Request Methods

contracts/PoolFactory.sol

@@ -53,6 +53,7 @@ contract PoolFactory {
         Pool pool = new Pool(
             liquidityAsset,
             msg.sender,
+            address(_serviceConfiguration),
             settings,
             "ValyriaPoolToken",
             "VPT"

contracts/ServiceConfiguration.sol

@@ -21,6 +21,11 @@ contract ServiceConfiguration is AccessControl, IServiceConfiguration {
 
     mapping(address => bool) public isLiquidityAsset;
 
+    /**
+     * @dev Holds a reference to valid LoanFactories
+     */
+    mapping(address => bool) public isLoanFactory;
+
     /**
      * @dev Emitted when an address is changed.
      */
@@ -36,6 +41,11 @@ contract ServiceConfiguration is AccessControl, IServiceConfiguration {
      */
     event ProtocolPaused(bool paused);
 
+    /**
+     * @dev Emitted when a loan factory is set
+     */
+    event LoanFactorySet(address indexed factory, bool isValid);
+
     /**
      * @dev Constructor for the contract, which sets up the default roles and
      * owners.
@@ -78,4 +88,16 @@ contract ServiceConfiguration is AccessControl, IServiceConfiguration {
     function isOperator(address addr) external view returns (bool) {
         return hasRole(OPERATOR_ROLE, addr);
     }
+
+    /**
+     * @inheritdoc IServiceConfiguration
+     */
+    function setLoanFactory(address addr, bool isValid)
+        external
+        override
+        onlyOperator
+    {
+        isLoanFactory[addr] = isValid;
+        emit LoanFactorySet(addr, isValid);
+    }
 }

contracts/interfaces/ILoan.sol

@@ -26,6 +26,11 @@ struct ILoanNonFungibleCollateral {
 }
 
 interface ILoan {
+    /**
+     * @dev Emitted when a Loan's lifecycle state transitions
+     */
+    event LifeCycleStateTransition(ILoanLifeCycleState state);
+
     /**
      * @dev Emitted when collateral is posted to the loan.
      */
@@ -52,6 +57,8 @@ interface ILoan {
 
     function pool() external view returns (address);
 
+    function factory() external view returns (address);
+
     function dropDeadTimestamp() external view returns (uint256);
 
     function cancelRequested() external returns (ILoanLifeCycleState);
@@ -90,4 +97,6 @@ interface ILoan {
     function principal() external returns (uint256);
 
     function fundingVault() external returns (FundingVault);
+
+    function markDefaulted() external returns (ILoanLifeCycleState);
 }

contracts/interfaces/IPool.sol

@@ -142,8 +142,8 @@ interface IPool is IERC4626 {
     function fundLoan(address) external;
 
     /**
-     * @dev Called by the pool manager, marks a loan as in default, updating pool accounting and allowing loan
-     * collateral to be claimed.
+     * @dev Called by the pool manager, this marks a loan as in default, triggering liquiditation
+     * proceedings and updating pool accounting.
      */
-    function markLoanAsInDefault(address) external;
+    function defaultLoan(address) external;
 }

contracts/interfaces/IServiceConfiguration.sol

@@ -15,4 +15,18 @@ interface IServiceConfiguration is IAccessControl {
     function paused() external view returns (bool);
 
     function isLiquidityAsset(address addr) external view returns (bool);
+
+    /**
+     * @dev checks if an address is a valid loan factory
+     * @param addr Address of loan factory
+     * @return bool whether the loan factory is valid
+     */
+    function isLoanFactory(address addr) external view returns (bool);
+
+    /**
+     * @dev Sets whether a loan factory is valid
+     * @param addr Address of loan factory
+     * @param isValid Whether the loan factory is valid
+     */
+    function setLoanFactory(address addr, bool isValid) external;
 }

contracts/libraries/PoolLib.sol

@@ -6,7 +6,10 @@ import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol
 import {SafeMath} from "@openzeppelin/contracts/utils/math/SafeMath.sol";
 import "../interfaces/ILoan.sol";
 import "../interfaces/IPool.sol";
+import "../interfaces/ILoan.sol";
+import "../interfaces/IServiceConfiguration.sol";
 import "../FirstLossVault.sol";
+import "../LoanFactory.sol";
 
 /**
  * @title Collection of functions used by the Pool
@@ -45,6 +48,11 @@ library PoolLib {
         uint256 shares
     );
 
+    /**
+     * @dev See IPool for event definition
+     */
+    event LoanDefaulted(address indexed loan);
+
     /**
      * @dev Transfers first loss to the vault.
      * @param liquidityAsset Pool liquidity asset
@@ -237,4 +245,24 @@ library PoolLib {
     ) public view returns (uint256) {
         return currentWithdrawPeriod(activatedAt, withdrawalWindowDuration) + 1;
     }
+
+    /**
+     * @dev Determines whether an address corresponds to a pool loan
+     * @param loan address of loan
+     * @param serviceConfiguration address of service configuration
+     * @param pool address of pool
+     */
+    function isPoolLoan(
+        address loan,
+        address serviceConfiguration,
+        address pool
+    ) public view returns (bool) {
+        address factory = ILoan(loan).factory();
+        return
+            IServiceConfiguration(serviceConfiguration).isLoanFactory(
+                factory
+            ) &&
+            LoanFactory(factory).isLoan(loan) &&
+            ILoan(loan).pool() == pool;
+    }
 }

contracts/mocks/PoolLibTestWrapper.sol

@@ -3,6 +3,7 @@ pragma solidity ^0.8.16;
 
 import "../libraries/PoolLib.sol";
 import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
+import "../interfaces/IPool.sol";
 
 /**
  * @title PoolLibTestWrapper
@@ -119,4 +120,12 @@ contract PoolLibTestWrapper is ERC20("PoolLibTest", "PLT") {
                 _mint
             );
     }
+
+    function isPoolLoan(
+        address loan,
+        address serviceConfiguration,
+        address pool
+    ) public view returns (bool) {
+        return PoolLib.isPoolLoan(loan, serviceConfiguration, pool);
+    }
 }

contracts/permissioned/PermissionedPool.sol

@@ -44,10 +44,20 @@ contract PermissionedPool is Pool {
     constructor(
         address liquidityAsset,
         address poolManager,
+        address serviceConfiguration,
         IPoolConfigurableSettings memory poolSettings,
         string memory tokenName,
         string memory tokenSymbol
-    ) Pool(liquidityAsset, poolManager, poolSettings, tokenName, tokenSymbol) {
+    )
+        Pool(
+            liquidityAsset,
+            poolManager,
+            serviceConfiguration,
+            poolSettings,
+            tokenName,
+            tokenSymbol
+        )
+    {
         _poolAccessControl = new PoolAccessControl(address(this));
     }
 

contracts/permissioned/PermissionedPoolFactory.sol

@@ -60,9 +60,10 @@ contract PermissionedPoolFactory is PoolFactory {
             firstLossInitialMinimum,
             withdrawRequestPeriodDuration
         );
-        Pool pool = new PermissionedPool(
+        PermissionedPool pool = new PermissionedPool(
             liquidityAsset,
             msg.sender,
+            address(_serviceConfiguration),
             settings,
             "ValyriaPoolToken",
             "VPT"