Redshift add early startup option, rewrite to use toINI and add more options

nixos/modules/services/x11/redshift.nix

@@ -47,6 +47,25 @@ in {
       '';
     };
 
+    method = mkOption {
+      type = types.nullOr (types.enum [ "drm" "randr" "vidmode" "dummy" ]);
+      default = null;
+      description = ''
+        Method to use for making the adjustments.
+      '';
+    };
+
+    methodOptions = mkOption {
+      type = types.attrsOf types.str;
+      default = {};
+      description = ''
+        Additional method specific options to pass to redshift.
+      '';
+      example = {
+        crtc = "0";
+      };
+    };
+
     temperature = {
       day = mkOption {
         type = types.int;
@@ -85,6 +104,16 @@ in {
       };
     };
 
+    fade = mkOption {
+      type = types.nullOr types.bool;
+      default = null;
+      apply = lib.mapNullable (f: if f then 1 else 0);
+      description = ''
+        Enable fading between color temperatures when redshift
+        starts or stops.
+      '';
+    };
+
     package = mkOption {
       type = types.package;
       default = pkgs.redshift;
@@ -94,6 +123,15 @@ in {
       '';
     };
 
+    extraConfig = mkOption {
+      type = types.attrsOf types.string;
+      default = {};
+      description = ''
+        Additional options to append to the [redshift]
+        section of the configuration file (see man redshift).
+      '';
+    };
+
     extraOptions = mkOption {
       type = types.listOf types.str;
       default = [];
@@ -103,6 +141,16 @@ in {
         <command>redshift</command>.
       '';
     };
+
+    earlyStartup = mkOption {
+      type = types.bool;
+      default = false;
+      description = ''
+        Start redshift before the graphical interface is up.
+        This will automatically set the method to "drm".
+      '';
+    };
+
   };
 
   config = mkIf cfg.enable {
@@ -121,23 +169,42 @@ in {
 
     services.geoclue2.enable = mkIf (cfg.provider == "geoclue2") true;
 
+    services.redshift.method = mkIf cfg.earlyStartup "drm";
+
     systemd.user.services.redshift = 
     let
-      providerString = 
-        if cfg.provider == "manual"
-        then "${cfg.latitude}:${cfg.longitude}"
-        else cfg.provider;
-    in
+      allOptions = {
+          redshift = {
+            temp-day = cfg.temperature.day;
+            temp-night = cfg.temperature.night;
+            brightness-day = cfg.brightness.day;
+            brightness-night = cfg.brightness.night;
+            location-provider = cfg.provider;
+            adjustment-method = cfg.method;
+            fade = cfg.fade;
+          } // cfg.extraConfig;
+          manual = {
+            lat = cfg.latitude;
+            lon = cfg.longitude;
+          };
+        } // lib.optionalAttrs (!builtins.isNull cfg.method) {
+          "${cfg.method}" = cfg.methodOptions;
+        };
+      configFile = lib.generators.toINI {}
+      ( lib.filterAttrsRecursive (n: v: v != null) allOptions );
+      target =
+        if cfg.earlyStartup
+        then "basic.target"
+        else "graphical-session.target";
+   in
     {
       description = "Redshift colour temperature adjuster";
-      wantedBy = [ "graphical-session.target" ];
-      partOf = [ "graphical-session.target" ];
+      wantedBy = [ target ];
+      partOf = [ target ];
       serviceConfig = {
         ExecStart = ''
           ${cfg.package}/bin/redshift \
-            -l ${providerString} \
-            -t ${toString cfg.temperature.day}:${toString cfg.temperature.night} \
-            -b ${toString cfg.brightness.day}:${toString cfg.brightness.night} \
+          -c ${builtins.toFile "redshift-config" configFile} \
             ${lib.strings.concatStringsSep " " cfg.extraOptions}
         '';
         RestartSec = 3;