build.gradle

plugins {
	id 'fabric-loom' version '1.8-SNAPSHOT'
	id 'maven-publish'
}

base {
	archivesName = project.archives_base_name
	version = project.mod_version
	group = project.maven_group
}

loom {
	accessWidenerPath = file('src/main/resources/seedmapper.aw')
}

repositories {
	mavenCentral()
	maven {
		name = 'xpple'
		url = 'https://maven.xpple.dev/maven2'
	}
	maven {
		name = 'ParchmentMC'
		url = 'https://maven.parchmentmc.org'
	}
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings loom.layered {
		officialMojangMappings {
			nameSyntheticMembers = true
		}
		parchment "org.parchmentmc.data:${project.parchment_mappings}"
	}
	modImplementation "net.fabricmc:fabric-loader:${project.fabric_loader_version}"

	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"

	include modImplementation("dev.xpple:clientarguments:${project.clientarguments_version}")
	include modImplementation("dev.xpple:betterconfig-fabric:${project.betterconfig_version}")

	testImplementation platform("org.junit:junit-bom:${project.junit_version}")
	testImplementation 'org.junit.jupiter:junit-jupiter'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

processResources {
	def props = [version: project.mod_version, loader_version: project.fabric_loader_version]
	inputs.properties props
	filteringCharset "UTF-8"

	filesMatching("fabric.mod.json") {
		expand props
	}

	from("LICENSE") {
		rename {"${it}_${project.base.archivesName.get()}"}
	}

	from("src/main/c/LICENSE") {
		rename {"${it}_cubiomes"}
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.release = 23
}

java {
	sourceCompatibility = JavaVersion.VERSION_23
	targetCompatibility = JavaVersion.VERSION_23
}

test {
	useJUnitPlatform()
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			artifactId = project.base.archivesName.get()
			from components.java
		}
	}

	repositories {

	}
}