java17-build.gradle

plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '7.0.0'
    id 'maven-publish'
}

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(17))
}


group = 'me.playbosswar.com'
version = '8.11.2'
description = 'CommandTimer'

repositories {
    mavenLocal()
    maven {
        url = 'https://repo1.maven.org/maven2'
    }
    maven {
        url = 'https://papermc.io/repo/repository/maven-public/'
    }
    maven {
        url = 'https://repo.extendedclip.com/content/repositories/placeholderapi/'
    }
    maven {
        url = 'https://repo.codemc.io/repository/maven-snapshots/'
    }
}

shadowJar {
    dependencies {
        include(dependency('fr.minuskube.inv:smart-invs:1.2.7'))
        include(dependency('com.github.cryptomorin:XSeries:8.6.2'))
        include(dependency('joda-time:joda-time:2.10.13'))
        include(dependency('org.jeasy:easy-rules-core:4.1.0'))
        include(dependency('org.apache.commons:commons-text:1.10.0'))
        include(dependency('io.sentry:sentry:7.0.0'))
        include(dependency('com.j256.ormlite:ormlite-jdbc:6.1'))
    }
    // Needed in case the server software already packs sentry
    relocate 'io.sentry', 'me.playbosswar.com.commandtimer.sentry'
    archiveFileName = "commandtimer-java17.jar"
}

dependencies {
    implementation 'com.github.cryptomorin:XSeries:8.6.2'
    implementation 'fr.minuskube.inv:smart-invs:1.2.7'
    implementation 'joda-time:joda-time:2.10.13'
    implementation 'org.jeasy:easy-rules-core:4.1.0'
    implementation 'com.googlecode.json-simple:json-simple:1.1.1'
    implementation 'org.apache.commons:commons-text:1.10.0'
    implementation 'io.sentry:sentry:7.0.0'
    implementation 'com.j256.ormlite:ormlite-jdbc:6.1'
    compileOnly 'io.papermc.paper:paper-api:1.20.2-R0.1-SNAPSHOT'
    compileOnly 'me.clip:placeholderapi:2.11.6'
    compileOnly 'org.jetbrains:annotations:23.1.0'
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId = 'me.playbosswar.com'
            artifactId = 'commandtimer-java17'
            version = '8.11.2'

            from components.java
        }
    }
    repositories {
        maven {
            name = "GitHubPackages"
            url = "https://maven.pkg.github.com/titivermeesch/CommandTimer"
            credentials {
                username = System.getenv("GITHUB_ACTOR")
                password = System.getenv("GITHUB_TOKEN")
            }
        }
    }
}