build.gradle

buildscript {
	ext.kotlin_version = '1.0.6'
	repositories {
		jcenter()
		mavenCentral()
	}
	dependencies {
		classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
	}
}
plugins {
	id 'com.github.johnrengelman.shadow' version '1.2.4'
}
apply plugin: "kotlin"

project.version = '1.3'
project.group = 'me.nallar'

// Extended project information
ext.projectName = 'JarOpener'
ext.inceptionYear = '2016'
ext.packaging = 'jar'
ext.url = 'https://github.com/nallar/JarOpener'
ext.description = 'Opens up jar files for easy monkey-patching'
ext.organization = 'nallar.me'
ext.mainClassName = "me.nallar.JarOpener"

// Define variables
ext.buildNumber = System.getenv("BUILD_NUMBER") ?: 0
ext.ciSystem = System.getenv("JENKINS_URL") ? 'Jenkins' : 'unknown'
ext.commit = System.getenv("GIT_COMMIT") ?: 'unknown'

repositories {
	jcenter()
	maven { url='http://repo.nallar.me/' }
}

configurations {
	provided
	compile.extendsFrom provided
}

dependencies {
	compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
	compile 'me.nallar:JavaTransformer:1.3'
}

jar {
	baseName = project.name
	duplicatesStrategy = DuplicatesStrategy.EXCLUDE
	from((configurations.runtime - configurations.provided).filter { it.exists() }.collect {
		it.isDirectory() ? it : zipTree(it)
	}) {
		exclude "META-INF/**"
	}
}

jar.manifest.mainAttributes(
	"Main-Class": mainClassName,
	"Built-By": System.properties['user.name'],
	"Created-By": System.properties['java.vm.version'] + " (" + System.properties['java.vm.vendor'] + ")",
	"Implementation-Title": name,
	"Implementation-Version": version + "+" + ciSystem + "-b" + buildNumber + ".git-" + commit,
	"Implementation-Vendor": url)